Программа 12

Программа 12.7

4000 'ОБРАТНОЕ БПФ ДЛЯ ДЕЙСТВИТЕЛЬНЫХ СИГНАЛОВ

4010 'Перед входом в подпрограмму требуется указать порядок обратного ДПФ – N%

4020 'и заполнить элементы 0…N%/2 в массивах действительных и мнимых компонент

4030 'REX[ ] и IMX[ ], остальные элементы массивов игнорируются. Выходные

4040 'данные размещаются в массиве REX[ ], а в IMX[ ] все элементы нулевые.

4050 '

4060 '

4070 FOR K% = (N%/2+1) TO (N%-1) 'Введение симметрии в частотной области

4080 REX[K%] = REX[N%-K%] '(аналогично Программе 12.1)

4090 IMX[K%] = -IMX[N%-K%]

4100 NEXT K%

4110 '

4120 FOR K% = 0 TO N%-1 'Сложение действительной и мнимой частей

4130 REX[K%] = REX[K%]+IMX[K%]

4140 NEXT K%

4150 '

4160 GOSUB 3000 'Вычисление прямого ДПФ (Программа 12.6)

4170 '

4180 FOR I% = 0 TO N%-1 'Сложение действительной и мнимой частей

4190 REX[I%] = (REX[I%]+IMX[I%])/N% 'и деление на N% во временной области

4200 IMX[I%] = 0

4210 NEXT I%

4220 '

4230 RETURN