Программа 8

Программа 8.2.

100 'ДИСКРЕТНОЕ ПРЕОБРАЗОВАНИЕ ФУРЬЕ

110 'Отсчёты частотного представления сигнала, помещаемые в массивы REX[] и IMX[],

120 'рассчитываются по отсчётам сигнала во временной области, записанным в XX[].

130 '

140 DIM XX[511] 'XX[ ] содержит сигнал во временной области

150 DIM REX[256] 'REX[ ] содержит действительную часть частотного представления

160 DIM IMX[256] 'IMX[ ] содержит мнимую часть частотного представления

170 '

180 PI = 3.14159265 'Определение константы пи

190 N% = 512 'N% - это число отсчётов в массиве XX[ ]

200 '

210 GOSUB XXXX 'Предполагаемая подпрограмма загрузки данных в массив XX[ ]

220 '

230 '

240 FOR K% = 0 TO 256 'Обнуление массивов REX[ ] и IMX[ ], чтобы их можно было

250 REX[K%] = 0 'использовать в качестве аккумуляторов

260 IMX[K%] = 0

270 NEXT K%

280 '

290 ' 'Корреляция XX[ ] с косинусной и синусной базисными функциями (8.4)

300 '

310 FOR K% = 0 TO 256 'K% пробегает по всем отсчётам в массивах REX[ ] и IMX[ ]

320 FOR I% = 0 TO 511 'I% пробегает по всем отсчётам массива XX[ ]

330 '

340 REX[K%] = REX[K%] + XX[I%] * COS(2*PI*K%*I%/N%)

350 IMX[K%] = IMX[K%] - XX[I%] * SIN(2*PI*K%*I%/N%)

360 '

370 NEXT I%

380 NEXT K%

390 '

400 END