Программа 2

Программа 2.3.

100 'ВЫЧИСЛЕНИЕ ГИСТОГРАММЫ, СРЕДНЕГО ЗНАЧЕНИЯ И СКО
110 '
120 DIM X%[25000] 'Ячейки с X%[0] по X%[25000] хранят значения обрабатываемого сигнала
130 DIM H%[255] ' В ячейки с H%[0] по H%[255] записываются значения гистограммы
140 N% = 25001 'Количество точек в сигнале
150 '
160 FOR I% = 0 TO 255 'Обнуление ячеек гистограммы, необходимое для накопления
170 H%[I%] = 0
180 NEXT I%
190 '
200 GOSUB XXXX 'Некоторая подпрограмма, которая загружает сигнал в массив X%[ ]
210 '
220 FOR I% = 0 TO 25000 'Вычисление гистограммы для 25001 точек
230 H%[ X%[I%] ] = H%[ X%[I%] ] + 1
240 NEXT I%
250 '
260 MEAN = 0 'Вычисление среднего значения в соответствии с выражением (2.6)
270 FOR I% = 0 TO 255
280 MEAN = MEAN + I% * H%[I%]
290 NEXT I%
300 MEAN = MEAN / N%
310 '
320 VARIANCE = 0 'Вычисление СКО в соответствии с выражением (2.7)
330 FOR I% = 0 TO 255
340 VARIANCE = VARIANCE + H%[I%] * (I%-MEAN)^2
350 NEXT I%
360 VARIANCE = VARIANCE / (N%-1)
370 SD = SQR(VARIANCE)
380 '
390 PRINT MEAN SD 'Вывод среднего значения и СКО
400 '
410 END