Программа 12

Программа 12.2

5000 'КОМПЛЕКСНОЕ ДПФ НА ОСНОВЕ КОРРЕЛЯЦИОННОГО МЕТОДА

5010 'Порядок ДПФ N% и массивы действительных и мнимых компонент XR[ ] и XI[ ]

5020 'заполняются до входа в подпрограмму.

5030 'Найденные отсчёты спектра сигнала размещаются в массивах REX[ ] и IMX[ ]

5040 'Все сигналы содержат элементы с номерами 0…(N%-1).

5050 '

5060 PI = 3.14159265 'Константа

5070 '

5080 FOR K% = 0 TO N%-1 'Обнуление всех элементов массивов REX[ ] и IMX[ ],

5090 REX[K%] = 0 'которые используются для накопления суммы

5100 IMX[K%] = 0

5110 NEXT K%

5120 '

5130 FOR K% = 0 TO N%-1 'Цикл по всем частотам

5140 FOR I% = 0 TO N%-1 'Цикл по отсчётам комплексной синусоиды: SR и SI

5150 '

5160 SR = COS(2*PI*K%*I%/N%)'Вычисление отсчёта комплексной синусоиды

5170 SI = -SIN(2*PI*K%*I%/N%)

5180 REX[K%] = REX[K%] + XR[I%]*SR - XI[I%]*SI

5190 IMX[K%] = IMX[K%] + XR[I%]*SI + XI[I%]*SR

5200 '

5210 NEXT I%

5220 NEXT K%

5230 '

5240 RETURN